How to disable/enable office clipboard

Question: Is there any way that you can disable clipboard in Office 2016?

I don't mean show/hide status when coping or similar stuff from clipboard options. I mean to completely turn it off. It so intrusive that you cant turn it off from the application itself. Also it's a privacy concern because everything that you copy on your device goes there if any application (Excel, Word, etc.) is open. If they are all closed it will copy system clipboard to Office clipboard when you start Word/Excel.

I'm looking for any kind of solution (3rd party, registry, etc...). I have Win 7/64 bit and Office 2016/64 bit.

2 Answers

Here is a registry key we were provided by Microsoft to disable Office's clipboard. It's HKCU, so not as easily deployable, but seems to be functioning for our needs. More testing is ongoing.

To resolve this issue in Excel for Office 365, Excel 2019, Excel 2016 and Excel 2013, follow the steps in the "Registry key information" section.

1. Click Start, click Run, type regedit in the Open box, and then click OK.

2. Locate and then select the following registry subkey:

   HKEY_CURRENT_USER\Software\Microsoft\Office\xx.0\Common\General\

   Note xx.0 in this registry path corresponds to the Excel version (16.0 = Excel 2016, 15.0 = Excel 2013, 14.0 = Excel 2010).

3. On the Edit menu, point to New, and then click DWORD Value.
4. Type AcbControl, and then press Enter.
5. In the Details pane, right-click AcbControl, and then click Modify.
6. In the Value data box, type either decimal 2147483648 or hexadecimal 80000000, and then click OK.
7. Exit Registry Editor.

Disabling the Clipboard

Below is a workaround method to disable the clipboard functionality using a batch script with some conditional logic and a loop. There's also a method and some instructions below that outlining how to easily kill the loop. It uses some dynamic VB scripting language to help keep the process hidden in the background while running but it still gives you the control to use it and kill it as needed.

Batch Script

IF /I [%~N1]==[KillSwitch] TASKKILL /F /FI "WindowTitle eq ClearClip" & EXIT
IF NOT DEFINED MINIMIZED SET MINIMIZED=1 && START "" /MIN "%~F0" x && EXIT
@ECHO OFF
IF NOT [%~1]==[] GOTO :VBProcess
TITLE ClearClip
:LoopIt
ping -n 02 127.0.0.1 > nul
:WipeClip
cmd.exe /c echo off | clip
GOTO :LoopIt
:VBProcess
SET TempVBSFile=%temp%\~tmpVBSTemp.vbs
IF EXIST "%TempVBSFile%" DEL /F /Q "%TempVBSFile%"
ECHO Set WinScriptHost = CreateObject("WScript.Shell") >"%TempVBSFile%"
ECHO WinScriptHost.Run Chr(34) ^& "%~F0" ^& Chr(34), 0 >>"%TempVBSFile%"
ECHO Set WinScriptHost = Nothing >>"%TempVBSFile%"
CSCRIPT //nologo "%TempVBSFile%"
EXIT

Essentially this. . .

• Kills all processes with a title of "ClearClip" if the "KillSwitch" named file is passed to it as the first argument and then exits the script entirely (see Killing it with the Kill Switch)

• Starts [itself] the batch script again but minimized and with a passed dummy "x" value first argument

• Starts [itself] the batch script hidden with a dynamic VB script if the first argument passed to it is not null and then loops every 2 seconds clearing the clipboard

To use it

To use it or turn on the functionality to clear out the clipboard every 2 seconds, simply double-click or execute the batch script. If you have trouble or it does not work as expected, try running it elevated as administrator with a simple right-click | Run as administrator.

Killing it with the Kill Switch

1. Create a file with the name of KillSwitch.txt and place it right next to the batch script you saved that you execute to disable the clipboard

2. Drag and drop the KillSwitch.txt name file right into or onto the batch script that you execute to disable the clipboard, and this will kill the hidden background processes that clears the clipboard and then clipboard will be available again.

Further Resources

• If
• Start
• Goto
• Title
• .Run

• CScript

• CALL /?

  Substitution of batch parameters (%n) has been enhanced. You can
  now use the following optional syntax: %~1 - expands %1 removing any surrounding quotes (") %~f1 - expands %1 to a fully qualified path name %~n1 - expands %1 to a file name only

• Automatically clear your clipboard with ClipTTL